RemoteAR3/CMakeLists.txt

cmake_minimum_required(VERSION 3.25)
project(RemoteAR3)

set(CMAKE_CXX_STANDARD 20)

add_executable(RemoteAR3 src/main.cpp
        src/main_ext.cpp
        src/frame_sender.cpp
        src/image_process.cpp
        src/simple_mq.cpp
        src/simple_opengl.cpp
        src/third_party/rs.c)

add_subdirectory(src/image_process)
target_link_libraries(${PROJECT_NAME} ImageProcess)

# CUDA config
find_package(CUDAToolkit REQUIRED)
target_link_directories(${PROJECT_NAME} PRIVATE /usr/local/cuda/lib64)
target_link_libraries(${PROJECT_NAME} CUDA::cudart CUDA::cuda_driver)

# spdlog config
find_package(spdlog REQUIRED)
target_link_libraries(${PROJECT_NAME} spdlog::spdlog)
target_compile_definitions(${PROJECT_NAME} PRIVATE SPDLOG_ACTIVE_LEVEL=SPDLOG_LEVEL_TRACE)

# OpenCV config
find_package(OpenCV REQUIRED COMPONENTS cudaimgproc imgcodecs)
target_include_directories(${PROJECT_NAME} PRIVATE ${OpenCV_INCLUDE_DIRS})
target_link_libraries(${PROJECT_NAME} ${OpenCV_LIBS})

# glfw config
if (WIN32)
    set(GLFW_INCLUDE_DIR C:/BuildEssentials/VS2019Libs/include)
    set(GLFW_LIB_DIR C:/BuildEssentials/VS2019Libs/lib)
    find_library(GLFW_LIB glfw3 HINTS ${GLFW_LIB_DIR})
    target_include_directories(${PROJECT_NAME} PRIVATE ${GLFW_INCLUDE_DIR})
    target_link_libraries(${PROJECT_NAME} ${GLFW_LIB})
else ()
    find_package(glfw3 REQUIRED)
    target_link_libraries(${PROJECT_NAME} glfw)
endif ()

# glad config
if (WIN32)
    set(GLAD_DIR C:/BuildEssentials/Library/glad)
else ()
    set(GLAD_DIR /home/tpx/src/glad)
endif ()
target_include_directories(${PROJECT_NAME} PRIVATE ${GLAD_DIR}/include)
target_sources(${PROJECT_NAME} PRIVATE ${GLAD_DIR}/src/gl.c)

# imgui config
if (WIN32)
    set(IMGUI_DIR C:/BuildEssentials/Library/imgui-1.89.5)
else ()
    set(IMGUI_DIR /home/tpx/src/imgui-1.90)
endif ()
set(IMGUI_BACKENDS_DIR ${IMGUI_DIR}/backends)
target_include_directories(${PROJECT_NAME} PRIVATE ${IMGUI_DIR} ${IMGUI_BACKENDS_DIR})
target_sources(${PROJECT_NAME} PRIVATE
        ${IMGUI_DIR}/imgui.cpp
        ${IMGUI_DIR}/imgui_draw.cpp
        ${IMGUI_DIR}/imgui_tables.cpp
        ${IMGUI_DIR}/imgui_widgets.cpp
        ${IMGUI_DIR}/imgui_demo.cpp
        ${IMGUI_BACKENDS_DIR}/imgui_impl_glfw.cpp
        ${IMGUI_BACKENDS_DIR}/imgui_impl_opengl3.cpp)
target_compile_definitions(${PROJECT_NAME} PRIVATE HAVE_IMGUI)

# MVS config
if (WIN32)
    set(MVS_DIR "C:/BuildEssentials/Library/MVS/Development")
    set(MVS_INCLUDE_DIR ${MVS_DIR}/Includes)
    set(MVS_LIB_DIR ${MVS_DIR}/Libraries/win64)
else ()
    set(MVS_DIR /opt/MVS)
    set(MVS_INCLUDE_DIR ${MVS_DIR}/include)
    set(MVS_LIB_DIR ${MVS_DIR}/lib/64)
endif ()
find_library(MVS_LIB MvCameraControl HINTS ${MVS_LIB_DIR})
target_include_directories(${PROJECT_NAME} PRIVATE ${MVS_INCLUDE_DIR})
target_link_libraries(${PROJECT_NAME} ${MVS_LIB})
target_sources(${PROJECT_NAME} PRIVATE src/mvs_camera.cpp)

# NvEnc config
if (WIN32)
    set(NVCODEC_DIR C:/BuildEssentials/CUDA/Video_Codec_SDK_12.0.16)
    set(NVENC_LIB_DIR ${NVCODEC_DIR}/Lib/x64)
    find_library(NVENC_LIB nvencodeapi HINTS ${NVENC_LIB_DIR})
else ()
    set(NVCODEC_DIR /home/tpx/src/Video_Codec_SDK_12.0.16)
    find_library(NVENC_LIB nvidia-encode)
endif ()
set(NVCODEC_INCLUDE_DIR ${NVCODEC_DIR}/Interface)
target_include_directories(${PROJECT_NAME} PRIVATE ${NVCODEC_INCLUDE_DIR})
target_link_libraries(${PROJECT_NAME} ${NVENC_LIB})
target_sources(${PROJECT_NAME} PRIVATE src/video_encoder.cpp)

# yaml-cpp
find_package(yaml-cpp REQUIRED)
target_include_directories(${PROJECT_NAME} PRIVATE ${YAML_CPP_INCLUDE_DIR})
target_link_libraries(${PROJECT_NAME} ${YAML_CPP_LIBRARIES})

# Boost config
find_package(Boost REQUIRED COMPONENTS iostreams)
target_include_directories(${PROJECT_NAME} PRIVATE ${Boost_INCLUDE_DIRS})
target_link_libraries(${PROJECT_NAME} ${Boost_LIBRARIES})